DisabledScreenNotice.qml

/*
 * Copyright (C) 2016 Canonical Ltd.
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation; version 3.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 */
 
import QtQuick 2.15
import QtQuick.Layouts 1.1
import Lomiri.Components 1.3
import Lomiri.Session 0.1
import QtQuick.Window 2.2
import WindowManager 1.0
import "Components"
 
Item {
    id: root
 
    property var screen: null
    property var orientationLock: OrientationLock
    property alias overrideDeviceName: root.deviceConfiguration.overrideName
 
    property bool oskEnabled: false
 
    property alias deviceConfiguration: _deviceConfiguration
    DeviceConfiguration {
        id: _deviceConfiguration
    }
 
    Item {
        id: contentContainer
        objectName: "contentContainer"
        anchors.centerIn: parent
        height: rotation == 90 || rotation == 270 ? parent.width : parent.height
        width: rotation == 90 || rotation == 270 ? parent.height : parent.width
 
        property int angleFromPrimary: Screen.angleBetween(Screen.primaryOrientation, Screen.orientation)
        readonly property bool rotatedToPhysical: rotation === angleFromPrimary
 
        function matchPhysicalOrientation() {
            rotation = angleFromPrimary;
        }
 
        transformOrigin: Item.Center
 
        Rectangle {
            anchors.fill: parent
            color: LomiriColors.jet
        }
 
        VirtualTouchPad {
            objectName: "virtualTouchPad"
            anchors.fill: parent
            oskEnabled: root.oskEnabled
            showRotateButton: !contentContainer.rotatedToPhysical
 
            onRotate: contentContainer.matchPhysicalOrientation();
        }
    }
}